Format floating point number into double-byte fixed point number

Entry condition: Formatted floating-point operand in [R0].
Exit information: OV=1 overflow, OV=0 conversion success: The absolute value of the fixed-point number is in [R0] (double byte), the sign
is in bit 1FH, F0=1 is an integer, CY=1 is a one-byte integer and a one-byte decimal, otherwise it is a pure decimal.
Affected resources: PSW, A, B, R2, R3, R4, bit 1FH Stack requirements: 6 bytes
FTOD: LCALL MVR0; transfer [R0] to the first work area
MOV A, R2
JZ FTD4; the exponent is zero, pure decimal
JB ACC.7, FTD4; the exponent is negative, pure decimal
SETB C
SUBB A, #10H
JC FTD1
SETB OV; the exponent is greater than 16, overflow
RET
FTD1: SETB C
MOV A, R2
SUBB A, #8; is the exponent greater than 8?
JC FTD3
FTD2: MOV B,#10H ; if the exponent is greater than 8, convert it as a double-byte integer
LCALL FTD8
SETB F0 ; set up a double-byte integer flag
CLR C
CLR OV
RET
FTD3: MOV B,#8 ; convert it as a one-byte integer to a one-byte decimal
LCALL FTD8
SETB C ; set up a one-byte integer to a one-byte decimal flag
CLR F0
CLR OV
RET
FTD4: MOV B,#0 ; convert it as a pure decimal
LCALL FTD8
CLR OV ; set up a pure decimal flag
CLR F0
CLR C
RET
FTD8: MOV A,R2 ; right-normalize according to the specified number of integer digits
CJNE A,B,FTD9
MOV A,R3 ; transfer the double-byte result to [R0]
MOV @R0,A
INC R0
MOV A,R4
MOV @R0,A
DEC R0
RET
FTD9: CLR C
LCALL RR1 ; right-normalize once
SJMP FTD8