Application of 2 external interrupts of 51 MCU

;There are 8 LEDs connected to the P1 port of the 51 microcontroller.

;A push button switch K1 is connected to the external interrupt 0 input pin P3.2.

;A push button switch K2 is connected to the external interrupt 1 input pin P3.3.

; When K1 and K2 are not pressed, the 8 LEDs at port P1 will display as running lights.

;When only K1 (P3.2) is pressed, the 4 LEDs on the left and right flash alternately.

;When only K2 (P3.3) is pressed, all 8 LEDs of P1 port will flash.

;The two external interrupts have the same priority.

;=============================================

;The PROTSUE simulation interface is as follows:

;Image link: http://hi.baidu.com/%D7%F6%B6%F8%C2%DB%B5%C0/album/item/50c618c5f08ba9f48026ac6a.html#

;The following procedures can meet the requirements.

      ORG 0000H

      SJMP MAIN

      ORG 0003H

      SJMP X0_INT

      ORG 0013H

      SJMP X1_INT

;------------------------------------

MAIN:

      MOV SP, #60H

      MOV IE, #85H

      MOV A, #254

M_LOOP:

      MOV P1, A

      RL A

      CALL DL_500MS

      SJMP M_LOOP

;------------------------------------

X0_INT:

      PUSH PSW

      SETB RS1

      MOV P1, #0FH

SH_0:

      XRL P1, #255

      CALL DL_500MS

      JNB P3.2, SH_0

      POP PSW

      RETI

;------------------------------------

X1_INT:

      PUSH PSW

      SETB RS0

      MOV P1, #0

SH_1:

      XRL P1, #255

      CALL DL_500MS

      JNB P3.3, SH_1

      POP PSW

      RETI

;------------------------------Delay subroutine

DL_500MS:

      MOV R5, #9 ;1T

DL1: MOV R6, #128 ;1T

DL2: MOV R7, #215 ;1T

      NOP ;1T

DL3: DJNZ R7, DL3; 2T 2 * 215 = 430 T

      DJNZ R6, DL2 ;2T [1+1+430+2] * 128 = 55552 T

      DJNZ R5, DL1 ;2T [1+55552+2] * 9 = 499995 T

      RET ;2T 1 + 499995 + 2 = 499998 T

;------------------------------------

END