Multi-byte unsigned binary number division microcontroller assembly program example

Example: Divide (R2R3R4R5) by (R6R7), the quotient is sent to (R4R5), and the remainder is sent to (R2R3). Manual calculation method: 

1) Align the divisor from the high bit of the dividend and compare. 

2) If the former is greater than or equal to the latter, the quotient is 1, and the dividend is subtracted from the divisor to form a partial remainder. If the former is less than the latter, the quotient is 0. 

3) The partial remainder is shifted left by one bit, and the quotient is also shifted left by one bit. 

4) If the entire remainder is less than the divisor, exit. 

5) Compare the partial remainder with the divisor from the high bit 

6) Go to step 2). 

If the high 16 bits of the dividend are greater than or equal to the divisor, overflow occurs. 

NDIV: MOV A, R3 

CLR C 

SUBB A, R7 ; first compare whether overflow occurs 

MOV A, R2 

SUBB A, R6 

JNC NDVE1 ; overflow 

MOV B, #16 ; no overflow, 16 bits 

NDVL1: CLR C 

MOV A, R5 

RLC A 

MOV R5, A 

MOV A, R4 

RLC A 

MOV R4, A ; the dividend is shifted left by one bit, and the quotient is also shifted left by one bit 

MOV A, R3 

RLC A 

MOV R3, A 

MOV A, R2 

RLC A 

MOV R2, A 

MOV F0, C ; save the highest bit shifted out 

CLR C 

MOV A, R3 

SUBB A, R7 ; compare the partial remainder with the divisor 

MOV R1, A 

MOV A, R2 

SUBB A, R6 

JB F0, NDVM1 ; if the last highest bit = 1, then the quotient bit = 1 

JC NDVD1 ; if the partial remainder is less than the divisor, then the quotient bit = 0 

NDVM1: MOV R2, A 

MOV A, R1 

MOV R3, A ; return subtraction result 

INC R5 ; quotient = 1 

NDVD1: DJNZ B, NDVL1 ; loop 16 times 

CLR F0 

RET 

NDVE1: SETB F0 ; overflow flag 

RET