Floating point polynomial calculation

Entry conditions: The independent variable is in [R0], the polynomial coefficient is after the call instruction, and ends with 40H.
Exit information: When OV=0, the result is still in [R0], and when OV=1, there is an overflow.
Affected resources: DPTR, PSW, A, B, R2~R7, bits 1EH, 1FH Stack requirement: 4 bytes
FPLN: POP DPH ; Get the address where the polynomial coefficients are stored
POP DPL
XCH A,R0 ; R0 and R1 exchange roles, the independent variable is in [R1]
XCH A,R1
XCH A,R0
CLR A ; Clear the first work area
MOV R2,A
MOV R3,A
MOV R4,A
CLR 1FH
PLN1: CLR A ; Read a coefficient and load it into the second work area
MOVC A,@A+DPTR
MOV C,ACC.7
MOV 1EH,C
MOV C,ACC.6
MOV ACC.7,C
MOV R5,A
INC DPTR
CLR A
MOVC A,@A+DPTR
MOV R6,A
INC DPTR
CLR A
MOVC A,@A+DPTR
MOV R7,A
INC DPTR ;Point to the next coefficient
MOV C,1EH ;Compare two numbers
RRC A
XRL A,23H
RLC A
MOV F0,C ;Save the comparison result
LCALL AS1 ;Perform algebraic addition
CLR A ;Read the first byte of the next coefficient
MOVC A,@A+DPTR
CJNE A,#40H,PLN2;Is it the end mark?
XCH A,R0 ;Operation ends, restore the original roles of R0 and R1
XCH A,R1
XCH A,R0
LCALL MOV0 ;Pass the result back to [R0]
CLR A
INC DPTR
JMP @A+DPTR ;Return to the main program
PLN2: MOV A,@R1 ;Compare the signs of the independent variable and the intermediate result
XRL A,23H
RLC A
MOV 1FH,C ;Save the comparison result
LCALL MUL0 ;Perform multiplication
SJMP PLN1 ;Continue the next operation