Assembly language multi-byte BCD code addition and subtraction

(1) Label: BCDA Function: Multi-byte BCD code addition

Here is a multi-byte BCD code addition and subtraction subroutine written in MCU assembly language.
Entry conditions: byte number in R7, addend in [R0], addend in [R1].
Exit information: sum in [R0], highest carry in CY.
Affected resources: PSW, A, R2 Stack requirements: 2 bytes
BCDA: MOV A, R7; get byte number to R2
MOV R2, A
ADD A, R0; initialize data pointer
MOV R0, A
MOV A, R2
ADD A, R1
MOV R1, A
CLR C
BCD1: DEC R0; adjust data pointer
DEC R1
MOV A, @R0
ADDC A, @R1; add byte by byte
DA A; decimal adjustment
MOV @R0, A; store sum back to [R0]
DJNZ R2, BCD1; process all bytes
RET

Assembly language multi-byte BCD code addition and subtraction

(2) Label: BCDB Function: Multi-byte BCD code subtraction
Entry conditions: Byte number in R7, minuend in [R0], subtrahend in [R1].
Exit information: Difference in [R0], highest borrow in CY.
Affected resources: PSW, A, R2, R3 Stack requirement: 6 bytes
BCDB: LCALL NEG1; Complement the decimal value of the subtrahend [R1] LCALL
BCDA; Process as multi-byte BCD code addition
CPL C; Convert the carry flag of the complement addition to the borrow flag
MOV F0,C; Protect the borrow flag
LCALL NEG1; Restore the original value of the subtrahend [R1]
MOV C,F0; Restore the borrow flag
RET
NEG1: MOV A,R0; Complement the decimal value of [R1] Subroutine entry
XCH A,R1; Exchange pointer
XCH A,R0
LCALL NEG; Complement [R1] through [R0]
MOV A,R0
XCH A,R1; Exchange pointer
XCH A,R0
RET

(3) Label: NEG Function: Complement multi-byte BCD code

Assembly language multi-byte BCD code addition and subtraction

Entry condition: byte number in R7, operand in [R0].
Exit information: result is still in [R0].
Affected resources: PSW, A, R2, R3 Stack requirements: 2 bytes
NEG: MOV A,R7; load (byte number minus one) into R2
DEC A
MOV R2,A
MOV A,R0; protect pointer
MOV R3,A
NEG0: CLR C
MOV A,#99H
SUBB A,@R0; complement decimal byte
MOV @R0,A; store back to [R0]
INC R0; adjust data pointer
DJNZ R2,NEG0; process (R2) bytes
MOV A,#9AH; complement the lowest byte separately
SUBB A,@R0
MOV @R0,A
MOV A,R3; restore pointer
MOV R0,A
RET