Four-byte by three-byte unsigned number division program

;I saw someone online asking for a "four-byte by three-byte" subroutine, so I modified the program I wrote before and posted it below.
;I feel good about it, and think it is the _simplest_ and shortest_ program that can complete this function.
;The program is as follows, haha, sorry for the ugliness.
;===================================================================
    ORG 0000H
    LJMP START

    ORG 0030H ; Main program starts
START:
    MOV R7, #05H ; Set a 32-bit dividend
    MOV R6, #0F5H ; 05 F5 E0 FFH
    MOV R5, #0E0H ; = 99 999 999
    MOV R4, #0FFH
; MOV R3, #69H
    MOV R2, #98H ; Set a 24-bit divisor
    MOV R1, #96H ; 98 96 80H
    MOV R0, #80H ; = 10 000 000

    CALL DIV_32_24 ;Call the division subroutine

    SJMP $ ; Quotient, can be verified by a calculator: 00 00 00 09H
                     ; Remainder: 98 96 7FH = 9 999 999
;********************************************************
;* Four-byte/three-byte unsigned number division program *
;* Already tested *
;****************************************************
; R7R6R5R4 / R2R1R0 --> R7R6R5R4...32H31H30H
;
; Dividend R7R6R5R4, divisor R2R1R0
; Quotient R7R6R5R4, remainder 32H31H30H
; Because the number is large, this program uses: A, B, 33H and 32H 31H 30H
; The protection of these units should be performed in the main program
;-----------------------------------------------------------
DIV_32_24:
    CLR A
    MOV 30H, A
    MOV 31H, A
    MOV 32H, A
    MOV R3, #32 ;Number of loops
;---------------------------------------------------
    CLR C
DIV_LOOP:
    CALL SL_R7_R4
    CALL SL_32_30
        ;(32H31H30H <-- R7R6R5R4 <-- C) Shift left one bit
    MOV F0, C
;---------------------
    CLR C ;IF (32H31H30H >= R2R1R0) 32H31H30H -= R2R1R0;
    MOV A, 30H
    SUBB A, R0
    MOV 33H, A
    MOV A, 31H
    SUBB A, R1
    MOV B, A
    MOV A, 32H
    SUBB A, R2
    JNC DIV_2
    JNB F0, CPL_C ;If not enough, don’t save the difference
    CPL C
DIV_2:
    MOV 30H, 33H
    MOV 31H, B
    MOV 32H, A
CPL_C:
    CPL C
    DJNZ R3, DIV_LOOP
;--------------------------------------------------
SL_R7_R4:
    MOV A, R4
    RLC A
    MOV R4, A
    MOV A, R5
    RLC A
    MOV R5, A
    MOV A, R6
    RLC A
    MOV R6, A
    MOV A , R7
    RLC A
    MOV R7, A
    RET
;--------------------------
SL_32_30:
    MOV A, 30H
    RLC A
    MOV 30H, A
    MOV A, 31H
    RLC A
    MOV 31H, A
    MOV A, 32H
    RLC A
    MOV 32H, A
    RET
;-------------------------------------------------------------
    END
;================================================================